Программирование на языке Пролог для искусственного интеллекта

конкретизация( Терм, Терм1) :-
  % Терм1 - частный случай Терм'а
 копия( Терм1, Терм2),
  % Копия Терм1 с новыми переменными
 нумпер( Терм2, 0, _), !,
 Терм = Терм2.       % Успех, если Терм1 - частный случай Терм2
копия( Терм, НовТерм) :-
  % Копия Терм' а с новыми переменными
 asserta( copy( Терм) ),
 retract( сору( НовТерм) ), !.
посл_индекс( 0).     % Начальный индекс для 'сказано'
след_индекс( Инд) :- % Следующий индекс для 'сказано'
 retract( посл_индекс( ПослИнд) ), !,
 Инд is ПослИнд + 1,
 assert( посл_индекс( Инд) ).

Рис. 14.11. Оболочка экспертной системы: Вопросы к пользователю и ответы на вопросы 'почему'.

Отношение, подобное нумпер, часто входит в состав пролог-системы в качестве встроенной процедуры. Если это не так, то его можно реализовать программно следующим способом:

нумпер( Терм, N, Nплюс1) :-
 var( Терм), !, % Переменная?
 Терм = пер/N,
 Nплюс1 is N + 1.
нумпер( Терм, N, М) :-
 Терм =.. [Функтор | Аргументы], % Структура или атом
 нумарг( Аргументы, N, M).
  % Пронумеровать переменные в аргументах
нумарг( [], N, N) :- !.
нумарг( [X | Спис], N, M) :-
 нумпер( X, N, N1),
 нумарг( Спис, N1, М).

14.5.4. Процедура выдать

Процедура

выдать( Ответ)

приведенная на рис. 14.12, показывает пользователю окончательный результат консультационного сеанса и дает объяснения типа 'как'. Ответ включает в себя как ответ на вопрос пользователя, так и дерево вывода, демонстрирующее как система пришла к такому заключению. Сначала процедура выдать представляет пользователю свое заключение. Затем, если пользователь пожелает узнать, как это заключение достигнуто, то печатается дерево вывода в некоторой удобной для восприятия форме - это и есть объяснение типа 'как'. Форма объяснения показана в примере разд. 14.4.3.

14.5.5. Драйвер верхнего уровня

И наконец, для того, чтобы иметь удобный доступ к оболочке из интерпретатора Пролога, нам необходима процедура, выполняющая функцию 'драйвера'. На рис. 14.13 показано, как могла бы выглядеть предназначенная для этой цели процедура эксперт. Драйвер эксперт производит запуск трех основных модулей оболочки (рис. 14.10–14.12) и координирует их работу. Например:

?- эксперт.
Пожалуйста, спрашивайте:       % Приглашение пользователю
X это животное и голиаф это X. % Вопрос пользователя
Это правда:  голиаф имеет шерсть?
...
% Выдача заключения консультационного сеанса и
% объяснения типа 'как'
выдать( Ответ) :-
 nl, заключение( Ответ),
 nl, write( 'Хотите узнать, как?'),
 принять( Ответ1),
 ( Ответ1 = да, !, отобр( Ответ);
   true).                        % Показ решающего дерева
заключение( Ответ1 и Ответ2) :- !,
 заключение( Ответ1), write( 'и'),
 заключение( Ответ2).
заключение( Заключение было Найдено) :-
 write( Заключение).
% 'отобр' отображает полное решающее дерево
отобр( Решение) :-
 nl, отобр( Решение, 0), !.      % Отступ 0
отобр( Ответ1 и Ответ2, H) :- !, % Отступ H
 отобр( Ответ1, H),
 tab( H), write( 'и'), nl,
 отобр( Ответ2, H).
отобр( Ответ был Найден, H) :-   % Отступ H
 tab( H), печответ( Ответ),      % Показ заключения
 nl, tab( H),
 write( 'было'),
 отобр1( Найден, H).             % Показ доказательства
отобр1( Выведено из Ответ, H) :- !,
 write( Выведено), write( 'из'), % Показ имени правила
 nl, H1 is H + 4,
 отобр( Ответ, H1).              % Показ 'предшественника'